Power Point Macro Help

Hi,

First time posting; have a little problem.

I've been tasked to find out a way to import a whole bunch of frames into one slide, and have them go right after each other, with a 0.1 second delay between each.. (in essence, a flip book at 10 frames per second on one slide)

Now, you can create a macro to load in the image, no problem. I see the code in the macro edit. My problem is that it doesn't save the Custom Animation settings... namely the style (after previous) and the timing (0.1 second) that I want.

This code I found online...

With ActivePresentation.Slides(1).TimeLine
' Get the trigger type for the 1st effect in the main sequence.
Select Case .MainSequence(1).Timing.TriggerType
Case msoAnimTriggerOnPageClick
MsgBox "Animation triggered on mouse click"
Case msoAnimTriggerWithPrevious
MsgBox "Animation triggered with previous animation"
Case msoAnimTriggerAfterPrevious
MsgBox "Animation triggered after previous animation"
Case msoAnimTriggerOnShapeClick 'Triggered animation
MsgBox "Animation triggered by clicking on shape"
End Select
End With

http://skp.mvps.org/ppttimeline1.htm

This code will tell me what it's set to in a MessageBox. But how do I SET the item to one of those things. I'd like to say item.trigger = msoAnimTriggerAfterPrevious or something like that... is it that simple? Also, how would I go about setting the timing parameters? Is there some place to find what method/variable name of the powerpoint things?

THanks!
Rich

[John Wilson]

See if this helps point you in the right direction

Sub insertandanim()
Dim osld As Slide
Dim oshp As Shape
Dim oeff As Effect
Dim n As Integer
For n = 1 To 5
Set osld = ActivePresentation.Slides(1)
Set oshp = osld.Shapes.AddShape(msoShape32pointStar, 100, 100, 100, 100)
'different colours each time
Select Case n
Case Is = 1
oshp.Fill.ForeColor.RGB = vbBlue
Case Is = 2
oshp.Fill.ForeColor.RGB = vbRed
Case Is = 3
oshp.Fill.ForeColor.RGB = vbWhite
Case Is = 4
oshp.Fill.ForeColor.RGB = vbGreen
Case Is = 5
oshp.Fill.ForeColor.RGB = vbBlack
End Select
Set oeff = osld.TimeLine.MainSequence.AddEffect(oshp, msoAnimEffectBlinds, , msoAnimTriggerAfterPrevious)
With oeff
.Timing.TriggerDelayTime = 1
End With
Next
End Sub